#! /usr/bin/perl

use strict ;
use warnings ;

my $OMREPORT = '/opt/dell/srvadmin/bin/omreport' ;

my $prog = substr $0, rindex ( $0, '/' ) + 1 ;
my $Usage = <<USAGE ;
Usage: $prog [-v] [-q] [-d] [-f] controler
option v : be verbose
option q : be quiet
option d : show debug info
option f : action ; otherwise dry-run
USAGE
sub Usage { die "$_[0]$Usage" ; }
sub Error { die "[error] $prog: $_[0]\n" ; }
sub Warn  { warn "[warn] $prog: $_[0]\n" ; }

# usage: &GetOptions(ARG,ARG,..) defines $opt_ID as 1 or user spec'ed value
# usage: &GetOptions(\%opt,ARG,ARG,..) defines $opt{ID} as 1 or user value
# ARG = 'ID' | 'ID=SPC' | 'ID:SPC' for no-arg, required-arg or optional-arg
# ID  = perl identifier
# SPC = i|f|s for integer, fixedpoint real or string argument

use Getopt::Long ;
Getopt::Long::config ( 'no_ignore_case' ) ;
my %opt = () ; Usage '' unless GetOptions
  ( \%opt, qw(v q d f) ) ;
Usage "Arg count\n" unless @ARGV == 1 ;

$opt{v} ||= $opt{d} ;

my $ARG = shift ;

Error "don't have $OMREPORT" unless -x $OMREPORT ;

my @OMREPORT = ( $OMREPORT, qw(storage pdisk) ) ;
push @OMREPORT, "controller=$ARG" ;

if ( open LOG, '>>/tmp/omreport' )
  { printf LOG "%s\n", scalar localtime ;
    printf LOG "$prog [%s]\n", join ',', @ARGV ;
    printf LOG "running [%s] ...\n", join ',', @OMREPORT ;
    close LOG ;
  }

open REP, '-|', @OMREPORT or Error "can't popen [@OMREPORT] ($!)" ;
my @lines = <REP> ;
close REP ;

# Controller PERC 6/i Integrated (Embedded)
# ID                              : 0:0:0
# Status                          : Ok
# Name                            : Physical Disk 0:0:0
# State                           : Online
# Power Status                    : Not Applicable
# Bus Protocol                    : SATA
# Media                           : HDD

my $ids = 0 ;
my $onl = 0 ;
for my $line ( @lines )
  { chomp $line ;
    if ( $line =~ /^\w+\s+:\s+\S+/ )
      { my ( $key, $val ) = split /\s+:\s+/, $line, 2 ;
        if ( $key eq 'ID' )
          { print $line, "\n" if $opt{d} ;
            $ids ++ ;
          }
        elsif ( $key eq 'Status' )
          { print $line, "\n" if $opt{d} ;
            $onl ++ if $val eq 'Ok' ;
          }
      }
  }

if ( $opt{v} )
  { printf "run : @OMREPORT\n" ;
    printf "found id's   : %d\n", $ids ;
    printf "found online : %d\n", $onl ;
  }
printf "bad %d\n", $ids - $onl ;